###  AND  ###

#Metabolites

%agent:  met1(Loc~ex~in,c)
%agent:  met2(Loc~ex~in,c)


#transporters

%agent:  mtnH(Ex_pore,In_pore)

%agent:  cadA_gene(bs)
%agent:  cadA_mrna()
%agent:  cadA(Ex_pore,In_pore)

%agent:  arsB_gene(bs)
%agent:  arsB_mrna()
%agent:  arsB(Ex_pore,In_pore)

#Repressors

%agent:  czrA_gene(bs)
%agent:  czrA_mrna()
%agent:  czrA(ms,x)

%agent:  arsR_gene(bs)
%agent:  arsR_mrna()
%agent:  arsR(ms,x)

#Activators

%agent:  TF(x)

%agent:  P4_gene(bs1,bs2)
%agent:  P4_mrna()
%agent:  P4_AND()



# ######################################
# Influx of met1 through mtnH

'met1.mtnH' met1(Loc~ex), mtnH(Ex_pore) -> met1(Loc~ex!1),mtnH(Ex_pore!1) @ 'GeneralBinding'
'met1[ex-in]' met1(Loc~ex!1), mtnH(Ex_pore!1,In_pore) -> met1(Loc~in!2), mtnH(Ex_pore,In_pore!2) @ 'GeneralTransportRate'
'met1..mtnH' met1(Loc~in!2),mtnH(In_pore!2) -> met1(Loc~in),mtnH(In_pore) @ 'GeneralUnbinding'

# Eflux of met1 through arsB

'met1.arsB' met1(Loc~in), arsB(In_pore) -> met1(Loc~in!3),arsB(In_pore!3) @ 'GeneralBinding'
'met1[in-iex]' met1(Loc~in!3), arsB(In_pore!3,Ex_pore) -> arsB(In_pore,Ex_pore),met1(Loc~ex) @ 'GeneralTransportRate'




## influx met2

'met2.mtnH' met2(Loc~ex), mtnH(Ex_pore) -> met2(Loc~ex!5),mtnH(Ex_pore!5) @ 'GeneralBinding'
'met2[ex-in]' met2(Loc~ex!5), mtnH(Ex_pore!5,In_pore) -> met2(Loc~in!6), mtnH(Ex_pore,In_pore!6) @ 'GeneralTransportRate'
'met2..mtnH' met2(Loc~in!6),mtnH(In_pore!6) -> met2(Loc~in),mtnH(In_pore) @ 'GeneralUnbinding'

# Eflux of met1 through cadA

'met2.cadA' met2(Loc~in), cadA(In_pore) -> met2(Loc~in!7),cadA(In_pore!7) @ 'GeneralBinding'
'met2[in-ex]' met2(Loc~in!7), cadA(In_pore!7,Ex_pore) -> cadA(In_pore,Ex_pore),met2(Loc~ex) @ 'GeneralTransportRate'



# czrA

##regulation ##transc & transl

#'TF-met1_activation' TF(x),met1(Loc~in,c) <-> TF(x!3),met1(Loc~in,c!3) @ 'GeneralBinding','GeneralUnbinding'

'TF-czrA_on_off'  czrA_gene(bs),TF(x) <-> czrA_gene(bs!1),TF(x!1) @ 'TF_onRate','TF_offRate'

'czrA-transc' czrA_gene(bs) -> czrA_gene(bs),czrA_mrna() @ 'czrA_transcRate'
'czrA-transl' czrA_mrna() -> czrA_mrna(), czrA() @ 'czrA_translRate'


#arsR t&t

'arsR-NAR_on'  arsR_gene(bs),arsR(x) -> arsR_gene(bs!2),arsR(x!2) @ 'TF_onRate'
'arsR-NAR_off' arsR_gene(bs!2),arsR(x!2) -> arsR_gene(bs),arsR(x) @ 'TF_offRate'
'arsR-NAR-met2_off' arsR_gene(bs!2),arsR(ms,x!2),met2(Loc~in,c) -> arsR_gene(bs),met2(Loc~in,c) @ 'mBindingRate'


'arsR-transc' arsR_gene(bs) -> arsR_gene(bs),arsR_mrna() @ 'arsR_transcRate'
'arsR-transl' arsR_mrna() -> arsR_mrna(), arsR() @ 'arsR_translRate'


## transporters regulation t & t

#cadA

'czrA-cadA_on' cadA_gene(bs),czrA(x) -> cadA_gene(bs!5),czrA(x!5) @ 'TF_onRate'
'czrA-cadA_off' cadA_gene(bs!5),czrA(x!5) -> cadA_gene(bs),czrA(x) @ 'TF_offRate'
'czrA-cadA-met1_off' cadA_gene(bs!5),czrA(ms,x!5),met1(Loc~in,c) -> cadA_gene(bs),met1(Loc~in,c) @ 'mBindingRate'

'cadA-transc'  cadA_gene(bs) -> cadA_gene(bs),cadA_mrna() @ 'cadA_transcRate'
'cadA-transl'  cadA_mrna() -> cadA_mrna(),cadA() @ 'cadA_translRate'

#arsB

'arsR-arsB_on' arsB_gene(bs),arsR(x) -> arsB_gene(bs!6),arsR(x!6) @ 'TF_onRate'
'arsR-arsB_off' arsB_gene(bs!6),arsR(x!6) -> arsB_gene(bs),arsR(x) @ 'TF_offRate'
'arsR-arsB-met2_off'  arsB_gene(bs!6),arsR(ms,x!6),met2(Loc~in,c) -> arsB_gene(bs),met2(Loc~in,c) @ 'mBindingRate'

'arsB-transc'  arsB_gene(bs) -> arsB_gene(bs),arsB_mrna() @ 'arsB_transcRate'
'arsB-transl'  arsB_mrna() -> arsB_mrna(),arsB() @ 'arsB_translRate'

## ACTIVATORs

### P4 ###

#met1 regulation
'czrA-P4_on'  P4_gene(bs1),czrA(x) -> P4_gene(bs1!7),czrA(x!7) @ 'TF_onRate'
'czrA-P4_off'  P4_gene(bs1!7),czrA(x!7) -> P4_gene(bs1),czrA(x) @ 'TF_offRate'
'czrA-P4-met1_off'  P4_gene(bs1!7),czrA(ms,x!7),met1(Loc~in,c) -> P4_gene(bs1),met1(Loc~in,c) @ 'mBindingRate'

#met2 regulation
'arsR-P4_on'  P4_gene(bs2),arsR(x) -> P4_gene(bs2!8),arsR(x!8) @ 'TF_onRate'
'arsR-P4_off'  P4_gene(bs2!8),arsR(x!8) -> P4_gene(bs2),arsR(x) @ 'TF_offRate'
'arsR-P4-met2_off'  P4_gene(bs2!8),arsR(ms,x!8),met2(Loc~in,c) -> P4_gene(bs2),met2(Loc~in,c) @ 'mBindingRate'

# t&t &dim
'P4-transc'  P4_gene(bs1,bs2) -> P4_gene(bs1,bs2),P4_mrna() @ 'P4_transcRate'
'P4-transl'  P4_mrna() -> P4_mrna(),P4_AND() @ 'P4_translRate'


#decay

'cadA_mrna-dec'  cadA_mrna() -> @ 'mrna-decRate'
'cadA-dec'  cadA() -> @ 'prot-decRate'
'arsB_mrna-dec'  arsB_mrna() -> @ 'mrna-decRate'
'arsB-dec'  arsB() -> @ 'prot-decRate'
'czrA_mrna-dec'  czrA_mrna() -> @ 'mrna-decRate'
'czrA-dec'  czrA() -> @ 'prot-decRate'
'arsR_mrna-dec'  arsR_mrna() -> @ 'mrna-decRate'
'arsR-dec'  arsR() -> @ 'prot-decRate'

'TF-dec' TF() -> @ 'prot-decRate'

'P4_mrna-dec'  P4_mrna()-> @ 'mrna-decRate'
'P4_AND-dec'  P4_AND()-> @ 'prot-decRate'



###Rates
%var: 'mBindingRate' 1.0

%var: 'GeneralBinding' 0.003 # per molecules per second
%var: 'GeneralUnbinding' 0.3 
%var: 'GeneralTransportRate' 1.0

%var: 'TF_onRate' 0.001
%var: 'TF_offRate' 0.4



%var: 'czrA_transcRate' 0.05
%var: 'arsR_transcRate' 0.1
%var: 'cadA_transcRate' 0.04
%var: 'arsB_transcRate' 0.08
%var: 'P4_transcRate' 0.1


%var: 'czrA_translRate' 0.05
%var: 'arsR_translRate' 0.05
%var: 'cadA_translRate' 0.05
%var: 'arsB_translRate' 0.05
%var: 'P4_translRate' 0.05

%var: 'mrna-decRate' 0.0041
%var: 'prot-decRate' 0.00023




##init

%init: 3500 mtnH()
%init: 7000 TF()


%init: 1060 cadA()
%init: 1023 arsB()
%init: 430 czrA()
%init: 1284 arsR()

%init: 1 cadA_gene(bs)
%init: 1 arsB_gene(bs)
%init: 1 czrA_gene(bs)
%init: 1 arsR_gene(bs)
%init: 1 P4_gene()

#%init: 200 met2(Loc~in,c)


#obs

#%obs: 'm1IN' met1(Loc~in?)
#%obs: 'm1OUT' met1(Loc~ex?)

#%obs: 'm2In' met2(Loc~in?)
#%obs: 'M2OUT' met2(Loc~ex?)

%obs: 'czrA' czrA()
%obs: 'arsR' arsR()
%obs: 'arsB' arsB()
%obs: 'cadA' cadA()

%obs: 'P4' P4_AND()


%mod: [T] > 10000 do $ADD 20000 met2(Loc~ex)
%mod: [T] > 10000 do $ADD 20000 met1(Loc~ex)